本文旨在教給大家通過Phoenix WinNonlin中實現TMDD模型的建立，包含Partial MM消除的經驗模型和Full TMDD/QE/Qss等模型，並且對幾種模型的選擇提供一些參考。
1993 年，Gerhard Levy 首先提出了靶點介導的藥物處置( target mediated drug disposition，TMDD) 理論，用於描述藥物與生物靶點（例如，受體）的高親和力的現象，並闡述TMDD對藥物體內藥代動力學(PK)和藥效動力學(PD)的影響。 一般小分子藥物在體內靶點飽和的情況在模型擬合中經常被忽略，是因為在血漿或者組織中非特異性靶點容量很大，很難被飽和。某些藥物，特別是單抗大分子藥物，由於其分子量大，藥物分佈和消除都和一般藥物具有很大不同，且具有靶點特異性，那麼靶點介導的藥物處置過程就不容忽視。
下圖為大分子單抗不同劑量下的典型藥時曲線(濃度取對數)，通常拉斯维加斯9888將其分成4個階段，第一階段：藥物與靶點間快速形成平衡；第二階段：靶點處於飽和狀態，藥物主要通過異化作用消除，一級動力學，所以曲線呈現線性特徵；第三階段：靶點的飽和狀態逐步減弱，此時靶點介導藥物處置，這一消除途徑的影響越來越明顯，總體呈現為非線性 PK；第四階段：藥物濃度進一步降低，靶點遠未達飽和，靶點介導的消除和異化作用都為一級動力學過程，總體又呈現為線性PK [1]。
圖 | 大分子單抗不同劑量下的典型藥時曲線(濃度取對數）
全TMDD模型對應的微分方程：
QE近似模型：配體-受體結合和解離比其餘的系統過程快幾個數量級，所以可以假設Km(複合物內化)遠小於Koff(解離) ，通過一個解離平衡常數KD來代替Kon和Koff，完成模型簡化：
Qss近似模型：接着還可以把複合物內化速率和配體-受體結合解離看成一個整體，用Kss表示(複合物內化消除速率和結合-解離速率相當，不可忽略)，就簡化為Qss模型：
本教程使用的數據和代碼可以通過關注拉斯维加斯9888科技公眾號，回復關鍵詞：TMDD獲取
a) 準備數據：
b) 注意圖中標紅的部分，這是TMDD(或者非線性消除)的典型特徵，最好能夠有不同劑量的PK數據，因為劑量太低或者太高，TMDD特徵都不是很明顯。打開Phoenix WinNonlin軟件，File→New project，Import 準備好的數據，將數據發送到XY plot作圖：
c) 將數據send to→Phoenix model（Maximum likehood model），先設置靜脈二房室的基礎模型
d) 隨後點擊右側的Edit as graphical轉成圖形編輯模式，添加一條新的消除途徑， 並將其設置為Saturating。
e）映射好數據，設置好初始值，將算法設置為Naïve Pool。
f) 運行該任務，即可查看擬合結果。
a) 還是上面的數據，send to→Phoenix model（Maximum likehood model），點擊右邊的Edit as textual切換成代碼模式：
b) 在Model中替換為以下代碼[3]：
test(){
deriv(A1 = (-Cl*C -Cld*(C-C2) -(kon*C*R -koff*LR)*V))
deriv(A2 = Cld * (C-C2))
deriv(R = kin -kout*R -kon*C*R + koff*LR)
deriv(LR = kon*C*R - koff*LR - keRL*LR)
C = A1/V
C2 = A2/Vt
kin = R0*kout
dosepoint(A1)
sequence{R = R0}
error(CEps = 0.1)
#error(REps = 0.1) #當需要增加該觀測變量時，去掉前面的井號；
#error(LREps = 0.1) #當需要增加該觀測變量時，去掉前面的井號；
observe(CObs = C + C*CEps)
#observe(RObs = R + R*REps)#當需要增加該觀測變量時，去掉前面的井號；
#observe(LRObs = LR + LR*LREps) #當需要增加該觀測變量時，去掉前面的井號；
fixef(V = c(, 0.1, ), Vt = c(, 0.1, ), Cl = c(, .01, ), Cld = c(, 0.005, ), R0 = c(, 15, ))
fixef(kon = c(, 0.091, ), koff = c(, 0.0011, ), kout = c(, 0.014, ), keRL = c(, .0036, ))
secondary(Kd = koff / kon, Km = (koff + keRL)/kon)
}
備註：
· 前面帶#號的 "observe()" 和 "error()" 是成對的，增加對應的觀測變量時，成對的"observe()" 和 "error()" 前面的#號要求一起去掉；
· fixef()語句是表示參數初值設置的地方
c) 在main中進行數據映射，run options中將算法設置為Naïve Pool
d) 運行該任務，查看結果：拉斯维加斯9888可以對比一下分別提供C，C+R和C+R+LR觀測值的擬合結果：
拉斯维加斯9888從擬合圖看到，你和效果差不多，但是從參數 (Theta)結果可以看到，當用戶提供的信息越多，越豐富，參數擬合的精度也越高(RSE%越小)。但是通常來說，大多數時候，拉斯维加斯9888只有配體的數據，這也是在做Full TMDD模型時候的困境。
當數據有限時，比如只有配體的數據，那麼QE/Qss等簡化TMDD模型[4][5]，或許是不錯的選擇。TMDD簡化模型原理拉斯维加斯9888在第二部分常用模型中已經介紹，使用方法依然是複製代碼至model中使用，和前面的Full TMDD模型相同，代碼如下：
1. QE模型PML代碼：
test(){
#Adapted from Gibiansky et al. 2008 Journal of Pharmacokinetics and Pharmacodynamics". Parameterized for CL.
dosepoint(Atot)
#給藥劑量單位應換算為 pmol/kg. pmol (dose) / mL (Volume) = nM. 對於分子量為150KDa的分子來說，6700 pmol/kg 約等於 1 mg/kg
deriv(Atot = (-Kint*Ctot -((CL/V1)+(Q/V1)-Kint)*C1)*V1 + Q*C2)
Kint = Kdeg
Ctot = Atot / V1
C1 = 1/2*((Ctot-Rtot-KD)+sqrt((Ctot-Rtot-KD)^2+4*KD*Ctot))
Cugml = C1*0.15
#假設分子量為150KDa，將nM轉換為觀測數據的ug/mL的單位，如果分子不是150KDa，請按照實際分子量設置此處。
deriv(A2 = Q*C1 - Q*C2)
C2 = A2/V2
#Target：靶點部分的代碼
Ksyn = R0 * Kdeg
deriv(Rtot = Ksyn - Kdeg*Rtot-(Kint-Kdeg)*(Ctot-C1) )
Complex = Rtot*C1/(KD+C1)
Rfree = Rtot - Complex
ROpercent = Complex / Rtot * 100
error(CEps=0.1)
observe(CObs = Cugml*(1+CEps))
sequence{
Rtot = R0
}
stparm(V1 = tvV1)
stparm(V2 = tvV2)
stparm(R0 = tvR0)
stparm(CL = tvCL)
stparm(Q = tvQ)
stparm(KD = tvKD)
#stparm(Kint = tvKint)
#degradation/internalization of complex. Add this to the model if the degradation of complex is different from degradation of free Receptor
stparm(Kdeg = tvKdeg)
# degradation of Receptor.
fixef(tvR0 = c(, 12,)) # nM; steady state conc of the receptor
fixef(tvV1 = c(, 0.05, )) # ml/kg; Volume of central comp
fixef(tvV2 = c(, 0.1, )) # ml/kg; Volume of peripheral comp
fixef(tvCL = c(, 0.001, )) # ml/kg/d; Clearance
fixef(tvQ = c(, 0.003, )) # ml/kg/d; Intercompartmental clearance
fixef(tvKD = c(, 9, )) # nM; KD = dissociation constant = koff/kon
#fixef(tvKint = c(,0.2,)) #degradation of complex. Add this to the model if the degradation of complex is different from degradation of free receptor
fixef(tvKdeg = c(, 0.003, )) # 1/d; degradation rate of receptor. T1/2 = ln2/kdeg.
}
2. Qss模型PML代碼：
test(){
#Adapted from Gibiansky et al. 2008 Journal of Pharmacokinetics and Pharmacodynamics". Parameterized for CL.
dosepoint(Atot) #給藥劑量單位應換算為 pmol/kg. pmol (dose) / mL (Volume) = nM. 對於分子量為150KDa的分子來說，6700 pmol/kg 約等於 1 mg/kg
#mAb
deriv(Atot = (-Kint*Ctot -((CL/V1)+(Q/V1)-Kint)*C1)*V1 + Q*C2) #總藥量變化微分方程
Kint = Kdeg
Ctot = Atot / V1
C1 = 1/2*((Ctot-Rtot-Kss)+sqrt((Ctot-Rtot-Kss)^2+4*Kss*Ctot))
Cugml = C1*0.15
deriv(A2 = Q*(C1 -C2))
C2 = A2/V2
#Target：靶點部分的代碼
Ksyn = R0 * Kdeg
deriv(Rtot = Ksyn - Kdeg*Rtot-(Kint-Kdeg)*Complex )
Complex = Rtot*C1/(Kss+C1)
Rfree = Rtot - Complex
ROpercent = Complex / Rtot * 100
error(CEps=0.1)
observe(CObs = Cugml*(1+CEps))
sequence{
Rtot = R0
}
stparm(V1 = tvV1)
stparm(V2 = tvV2)
stparm(R0 = tvR0)
stparm(CL = tvCL)
stparm(Q = tvQ)
stparm(Kss = tvKss)
#stparm(Kint = tvKint) #degradation/internalization of complex. Add this to the model if the degradation of complex is different from degradation of free Receptor
stparm(Kdeg = tvKdeg) # degradation of Receptor.
fixef(tvR0 = c(, 12,)) # nM; steady state conc of the receptor
fixef(tvV1 = c(, 0.05, ))# ml/kg; Volume of central comp
fixef(tvV2 = c(, 0.1, ))# ml/kg; Volume of peripheral comp
fixef(tvCL = c(, 0.001, ))# ml/kg/d; Clearance
fixef(tvQ = c(, 0.003, )) # ml/kg/d; Intercompartmental clearance
fixef(tvKss = c(, 9, ))# nM; Kss = steady state constant =(koff+Kint)/kon
#fixef(tvKint = c(,0.2,)) #degradation of complex. Add this to the model if the degradation of complex is different from degradation of free receptor
fixef(tvKdeg = c(, 0.003, )) # 1/d; degradation rate of receptor. T1/2 = ln2/kdeg.
}
治療性單克隆抗體的典型參數範圍
上表是一些單克隆抗體參數的參考範圍，可以通過這個表格來換算一些參數的初值。另外，一些配體受體親和力參數，比如Kon，Koff，Kdeg等可以參考非臨床或者體外試驗的一些結果，可以更好的幫助大家獲取參數初值。
上面提到的多個模型，結合文獻[6]，拉斯维加斯9888可以對模型的選擇做個總結：
1. 從研究目的出發：
· 如果目的是為了首次臨床劑量的推算，那麼完整的TMDD或者基於生理的TMDD模型更加合適。
· 如果研究目的是為了預測數據進行末端半衰期的計算，Qss模型將不是合理的選擇，因為它不能準確預測藥物末端相的藥動學行為，此時QE將是更好的選擇。
2. 考慮獲取數據的局限：
· 只有配體濃度數據時，簡化的TMDD模型或經驗模型是更好的選擇
· 如果游離受體濃度遠大於藥物濃度時，則QE模型可能是無效的，準確性無法保證(主要是低劑量的時候)
· 數據信息量比較不足時，採樣點不充分，時間不夠長，MM經驗模型或許是一種穩健的選擇。
總之，拉斯维加斯9888可以根據目的和數據情況，綜合判斷可以選擇哪些模型來做。
本教程使用的數據和代碼可以通過關注拉斯维加斯9888科技公眾號，回復關鍵詞：TMDD獲取
參考文獻：
1. Peletier L A, Gabrielsson J. Dynamics of target-mediated drug disposition: characteristic profiles and parameter identification[J]. Journal of pharmacokinetics and pharmacodynamics, 2012, 39: 429-451.
2. Gabrielsson J, Weiner D. Pharmacokinetic and Pharmacodynamic Data Analysis, Concepts and Applications, 5th ed.
3. Mager D E, Jusko W J. General pharmacokinetic model for drugs exhibiting target-mediated drug disposition[J]. Journal of pharmacokinetics and pharmacodynamics, 2001, 28: 507-532.
4. Mager D E, Krzyzanski W. Quasi-equilibrium pharmacokinetic model for drugs exhibiting target-mediated drug disposition[J]. Pharmaceutical research, 2005, 22: 1589-1596.
5. Gibiansky L, Gibiansky E, Kakkar T, et al. Approximations of the target-mediated drug disposition model and identifiability of model parameters[J]. Journal of pharmacokinetics and pharmacodynamics, 2008, 35: 573-591.
